Dream Season 1996 - Flor…a's National Championship/Florida's National Championship on CD-ROM - Dream Season 1996.iso/mac/Dream Season '96/Dream Season '96.DXR/00003_Scroll Scripts.ls

Text File | 1997-03-19 | 4.3 KB | 137 lines

on ScrollDrag bDate
  global gCurrentRecord, gList, gWORLDSTARTDATE, gWORLDENDDATE, gSLIDERSPRITE, gSLIDERTHUMBSPRITE, gSLIDERTHUMBTEXTSPRITE, gSLIDERTHUMBTEXTOFFSET
  ScrollStopMedia()
  set NewRecord to 0
  set NewMedia to 0
  puppetSprite(gSLIDERTHUMBSPRITE, 1)
  puppetSprite(gSLIDERTHUMBTEXTSPRITE, 1)
  repeat while the mouseDown
    set the locH of sprite gSLIDERTHUMBSPRITE to constrainH(gSLIDERSPRITE, the mouseH)
    set h to the locH of sprite gSLIDERTHUMBSPRITE
    set the locH of sprite gSLIDERTHUMBTEXTSPRITE to h + gSLIDERTHUMBTEXTOFFSET
    set n to float(h - the left of sprite gSLIDERSPRITE) / the width of sprite gSLIDERSPRITE
    set index to GetScrollRecord(n, bDate)
    if bDate then
      set n to integer(((gWORLDENDDATE - gWORLDSTARTDATE) * n) + gWORLDSTARTDATE)
      set key to string(n)
    else
      set key to char 1 to 2 of word 1 of line index of gList & ".."
    end if
    set the text of cast "thumb scroll text" to key
    updateStage()
    if index <> gCurrentRecord then
      set NewRecord to 1
      LoadRecord(index)
      HideRecordPreviews()
      HideMedia()
      set NewMedia to 1
      set TimeForNewMedia to the ticks + (60 * 2)
    end if
    if (the ticks > TimeForNewMedia) and NewMedia then
      LoadMedia(1)
      set NewMedia to 0
    end if
  end repeat
  if NewRecord then
    if NewMedia then
      LoadMedia(1)
    end if
    go(marker(0))
  end if
end

on GetScrollRecord fPercent, bDate
  global gList, gWORLDSTARTDATE, gWORLDENDDATE
  set totalLines to the number of lines in gList
  if bDate then
    set n to integer(((gWORLDENDDATE - gWORLDSTARTDATE) * fPercent) + gWORLDSTARTDATE)
    set index to totalLines / 2
    set indexdiv to index / 2
    set t to line index of gList
    set t2 to line index + 1 of gList
    repeat while not ((n >= t) and (n < t2))
      if n < t then
        set index to index - indexdiv
      else
        set index to index + indexdiv
      end if
      set indexdiv to indexdiv / 2
      if indexdiv < 1 then
        set indexdiv to 1
      end if
      set t to line index of gList
      if index >= totalLines then
        set t2 to "9999"
        next repeat
      end if
      set t2 to line index + 1 of gList
    end repeat
  else
    set index to integer(totalLines * fPercent)
    if index < 1 then
      set index to 1
    end if
    if index > totalLines then
      set index to totalLines
    end if
  end if
  return index
end

on ScrollLeftRight dir, bDate
  global gCurrentRecord, gList, gWORLDSTARTDATE, gWORLDENDDATE, gSLIDERSPRITE, gSLIDERTHUMBSPRITE, gSLIDERTHUMBTEXTSPRITE, gSLIDERTHUMBTEXTOFFSET
  ScrollStopMedia()
  set NewMedia to 0
  set OK to 1
  puppetSprite(gSLIDERTHUMBSPRITE, 1)
  puppetSprite(gSLIDERTHUMBTEXTSPRITE, 1)
  repeat while OK and (((dir < 0) and IsPrevRecord()) or ((dir > 0) and IsNextRecord()))
    if dir < 0 then
      PrevRecord()
    else
      NextRecord()
    end if
    if bDate then
      set key to string(word 1 of line gCurrentRecord of gList)
      set n to integer(float(key - gWORLDSTARTDATE) / (gWORLDENDDATE - gWORLDSTARTDATE) * the width of sprite gSLIDERSPRITE)
    else
      set key to char 1 to 2 of word 1 of line gCurrentRecord of gList & ".."
      set n to integer(float(gCurrentRecord) / the number of lines in gList * the width of sprite gSLIDERSPRITE)
    end if
    set h to the left of sprite gSLIDERSPRITE + n
    set the locH of sprite gSLIDERTHUMBSPRITE to h
    set the locH of sprite gSLIDERTHUMBTEXTSPRITE to h + gSLIDERTHUMBTEXTOFFSET
    HideRecordPreviews()
    HideMedia()
    set NewMedia to 1
    set the text of cast "thumb scroll text" to key
    set OK to the stillDown
    set OK to the stillDown
    updateStage()
  end repeat
  if NewMedia then
    LoadMedia(1)
  end if
  go(marker(0))
end

on ScrollStopMedia
  global gVIDEOSPRITE, gAUDIOSPRITE
  if the visible of sprite (gVIDEOSPRITE + 1) then
    set n to the castNum of sprite (gVIDEOSPRITE + 1)
    if n > 0 then
      if the castType of cast n = #digitalVideo then
        set the movieRate of sprite (gVIDEOSPRITE + 1) to 0
      end if
    end if
  end if
  if the visible of sprite (gAUDIOSPRITE + 1) then
    set n to the castNum of sprite (gAUDIOSPRITE + 1)
    if n > 0 then
      if the castType of cast n = #digitalVideo then
        set the movieRate of sprite (gAUDIOSPRITE + 1) to 0
      end if
    end if
  end if
end